pkgs/vim/PKGBUILD

# Maintainer: Daryl Ronningen <relms@relms.dev>

pkgname=vim
pkgver=9.0.2153
pkgrel=1
pkgdesc="Vi Improved, a highly configurable, improved version of the vi text editor"
url="https://www.vim.org"
arch=("x86_64")
license=("custom:vim")
source=("https://github.com/vim/vim/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=("94cb108fa9c5454d295ace27fc47b130b68febdc8910dd6d2d899a8531840dde")

build() {
	cd $pkgname-$pkgver

	./configure \
		--prefix=/usr \
		--localstatedir=/var/lib/vim \
		--with-features=huge \
		--with-compiledby="Ikeda Linux" \
		--with-x=no \
		--disable-gui \
		--enable-multibyte \
		--enable-perlinterp=dynamic \
		--enable-python3interp=dynamic \
		--enable-rubyinterp=dynamic \
		--enable-luainterp=dynamic \
		--enable-tclinterp=dynamic \
		--disable-canberra

	make
}

package_vim() {
	cd $pkgname-$pkgver
	make VIMRCLOC=/etc DESTDIR=$pkgdir install

	# remove gvim.desktop as not included
	rm $pkgdir/usr/share/applications/gvim.desktop

	ln -s vim $pkgdir/usr/bin/vi

	# license
	install -Dm 644 runtime/doc/uganda.txt \
		$pkgdir/usr/share/licenses/$pkgname/license.txt
}