# Maintainer: Daryl Ronningen <relms@relms.dev>

pkgname=pacman
pkgver=6.0.2
pkgrel=1
pkgdesc="A library-based package manager with dependency support"
arch=("x86_64")
url="https://www.archlinux.org/pacman/"
license=("GPL")
depends=("curl" "libarchive" "libressl" "fakeroot")
makedepends=("ninja")
backup=(etc/pacman.conf etc/makepkg.conf)
source=(
	"https://sources.archlinux.org/other/pacman/$pkgname-$pkgver.tar.xz"
	"pacman.conf"
	"makepkg.conf"
)
sha256sums=(
	"7d8e3e8c5121aec0965df71f59bedf46052c6cf14f96365c4411ec3de0a4c1a5"
	"ae4611ae0236b27c56ca70bc509062d7ebe1863ed6a79e7a708e1cdcc56bb288"
	"78c9149c20d979ceaec5de71a5ea72d95705ba59d5903b595dff01e54075fe5b"
)

build() {
	cd $pkgname-$pkgver

	meson --prefix=/usr \
		--buildtype=plain \
		-Dscriptlet-shell=/usr/bin/bash \
		-Dldconfig=/usr/bin/ldconfig \
		build

	meson compile -C build
}

package() {
	cd $pkgname-$pkgver

	DESTDIR=$pkgdir meson install -C build

	install -dm755 $pkgdir/etc
	install -m644 $srcdir/pacman.conf $pkgdir/etc
	install -m644 $srcdir/makepkg.conf $pkgdir/etc
}