# Maintainer: Daryl Ronningen <relms@relms.dev>

pkgname=fakeroot
pkgver=1.32.2
pkgrel=1
pkgdesc="Tool for simulating superuser privileges"
arch=("x86_64")
url="https://tracker.debian.org/pkg/fakeroot"
license=("GPL")
#depends=("sed" "util-linux")
install=fakeroot.install
source=(
	"https://deb.debian.org/debian/pool/main/f/$pkgname/${pkgname}_${pkgver}.orig.tar.gz"
	"0001-musl-build.patch"
	"0002-do-not-redefine-id_t.patch"
)
sha256sums=(
	"f0f72b504f288eea5b043cd5fe37585bc163f5acaacd386e1976b1055686116d"
	"45eed64e0411bd1217ee3e0fade94dc299847f00993844bf3834412cf906db91"
	"81f0c5c2bc2683d1f698ea4497215ac416bf55ca868726148bcfb13769da1b7a"
)

prepare() {
	cd $pkgname-$pkgver

	patch -p1 <$srcdir/0001-musl-build.patch
	patch -p1 <$srcdir/0002-do-not-redefine-id_t.patch
}

build() {
	cd $pkgname-$pkgver

	./configure --prefix=/usr \
		--libdir=/usr/lib/libfakeroot \
		--disable-static \
		--with-ipc=sysv

	make
}

package() {
	cd $pkgname-$pkgver
	make DESTDIR="$pkgdir" install

	# install README for sysv/tcp usage
	install -Dm0644 README "$pkgdir/usr/share/doc/$pkgname/README"
}