# Maintainer: Daryl Ronningen <relms@relms.dev>

pkgname=readline
_basever=8.2
_patchlevel=007
pkgver=$_basever.$_patchlevel
pkgrel=1
pkgdesc="GNU readline library"
arch=("x86_64")
url="https://tiswww.case.edu/php/chet/readline/rltop.html"
license=("GPL")
depends=("ncurses")
backup=("etc/inputrc")
source=(
	"https://ftp.gnu.org/gnu/readline/readline-$_basever.tar.gz"
	"inputrc"
	"readline82-001.patch"
	"readline82-002.patch"
	"readline82-003.patch"
	"readline82-004.patch"
	"readline82-005.patch"
	"readline82-006.patch"
	"readline82-007.patch"
)
sha256sums=(
	"3feb7171f16a84ee82ca18a36d7b9be109a52c04f492a053331d7d1095007c35"
	"182e38c1eb37c5e84cb84c40a2121d5ec149aad9cfd372eba9e5cee7bb9b9f5c"
	"bbf97f1ec40a929edab5aa81998c1e2ef435436c597754916e6a5868f273aff7"
	"e06503822c62f7bc0d9f387d4c78c09e0ce56e53872011363c74786c7cd4c053"
	"24f587ba46b46ed2b1868ccaf9947504feba154bb8faabd4adaea63ef7e6acb0"
	"79572eeaeb82afdc6869d7ad4cba9d4f519b1218070e17fa90bbecd49bd525ac"
	"622ba387dae5c185afb4b9b20634804e5f6c1c6e5e87ebee7c35a8f065114c99"
	"c7b45ff8c0d24d81482e6e0677e81563d13c74241f7b86c4de00d239bc81f5a1"
	"5911a5b980d7900aabdbee483f86dab7056851e6400efb002776a0a4a1bab6f6"
)

prepare() {
	cd $pkgname-$_basever
	for ((_p = 1; _p <= $((10#${_patchlevel})); _p++)); do
		msg "applying patch readline${_basever//./}-$(printf "%03d" $_p)"
		patch -p0 -i ../readline${_basever//./}-$(printf "%03d" $_p).patch
	done
}

build() {
	cd $pkgname-$_basever

	./configure --prefix=/usr
	make SHLIB_LIBS=-lncurses
}

package() {
	cd $pkgname-$_basever

	make DESTDIR=$pkgdir install
	install -Dm644 $srcdir/inputrc $pkgdir/etc/inputrc
}