pkgname=rust
pkgver=1.74.1
pkgrel=1
pkgdesc="Systems programming language focused on safety, speed and concurrency"
arch=("x86_64")
url="https://www.rust-lang.org/"
license=("Apache" "MIT")
depends=("curl" "rust")
source=("https://static.rust-lang.org/dist/rustc-$pkgver-src.tar.gz" "config.toml" "0001-Update-openssl-version-for-libresssl-3.8.2.patch")
sha256sums=(
	"67db3e22fc9921c885baae5953ba144fc474cde29ec69ab56d43ce764206231d"
	"da61598a69261649008f2a1710746574e53e159a00cc6ee8fe3a41f4f9db0227"
	"8d27a3cf137acefe1dcd9716f23c94567d7a85253a37f96b74342a677effc5dc"
)

prepare() {
	cd rustc-$pkgver-src

	cp $srcdir/config.toml .

	patch -p1 <$srcdir/0001-Update-openssl-version-for-libresssl-3.8.2.patch

	cd src/tools/cargo
	cargo vendor ../../../vendor/
	cargo update --recursive
}

build() {
	cd rustc-$pkgver-src

	export RUST_BACKTRACE=1
	unset RUSTFLAGS

	DESTDIR=$srcdir/rust-build python3 ./x.py install
}

package() {
	cp -r $srcdir/rust-build/* $pkgdir/

	rm $pkgdir/usr/bin/*.old
	rm $pkgdir/usr/lib/rustlib/{components,install.log,rust-installer-version,uninstall.sh}
	rm $pkgdir/usr/lib/rustlib/manifest-*
}