# Maintainer: Daryl Ronningen <relms@relms.dev>

pkgname=busybox
pkgver=1.36.1
pkgrel=1
pkgdesc="Utilities for rescue and embedded systems"
arch=("x86_64")
url="https://www.busybox.net"
license=('GPL-2.0-ONLY')
#makedepends=("ncurses")
source=("https://busybox.net/downloads/busybox-$pkgver.tar.bz2"
        "config")
sha256sums=('b8cc24c9574d809e7279c3be349795c5d5ceb6fdf19ca709f80cde50e47de314'
            '5292742e2fef3edc1b4d7aa32dfda6229feb169aaa7891aace720608a299e7c8')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  cp "$srcdir"/config .config
  # reproducible build
  export KCONFIG_NOTIMESTAMP=1
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make install

  # Move all applets into /usr/bin
  cd "$pkgdir"
  mv bin/* usr/bin/
  mv sbin/* usr/bin/
  mv usr/sbin/* usr/bin/
  rm -rf bin/ sbin/ usr/sbin/
  cd "$srcdir/$pkgname-$pkgver"

  # docs
  install -Dm644 docs/busybox.1 "$pkgdir"/usr/share/man/man1/busybox.1
  for doc in BusyBox.html BusyBox.txt; do
    install -Dm644 docs/$doc "$pkgdir"/usr/share/doc/$pkgname/$doc
  done
}